blob: e53aa77eb35b3a530a904e856ddf418e59aab599 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi
_rpmversion=2.2.1388.37-1
pkgver=2.2.1388.37
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind.'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('x86_64' 'i686')
depends=('gtk3' 'libcups' 'nss' 'alsa-lib' 'libxss' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'hicolor-icon-theme')
makedepends=('w3m')
optdepends=(
'vivaldi-ffmpeg-codecs: playback of proprietary video/audio'
'pepper-flash: flash support'
'google-chrome: Widevine DRM Plugin'
'vivaldi-widevine: Widevine DRM Plugin'
'libnotify: native notifications'
)
source_x86_64=("https://downloads.vivaldi.com/stable/vivaldi-stable-${_rpmversion}.x86_64.rpm")
source_i686=("https://downloads.vivaldi.com/stable/vivaldi-stable-${_rpmversion}.i386.rpm")
sha512sums_x86_64=('28e1e28135ea173dc08f32fd06d754c0abf7f897ea70236b4ce449967c4dbab71199131418f0cc134741398102c893e09d40b1af6f1fd82b42a6367d46ef6363')
sha512sums_i686=('d58e67dbcf7752c98812b03b26008181d1dfaba0103b1fc9f98db3b22b6ddb563d399989fd1ab7cc488ff8d5223829b479a43be360face86e6d96e4d5df746ec')
package() {
cp -a {opt,usr} "$pkgdir"
# suid sandbox
chmod 4755 "$pkgdir/opt/$pkgname/vivaldi-sandbox"
# make /usr/bin/vivaldi-stable available
binf="$pkgdir/usr/bin/vivaldi-stable"
if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
install -dm755 "$pkgdir/usr/bin"
ln -s /opt/vivaldi/vivaldi "$binf"
fi
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/$pkgname/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/$pkgname.png"
done
# license
install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
strings "$pkgdir/opt/vivaldi/locales/en-US.pak" \
| tr '\n' ' ' \
| sed -rne 's/.*(<html lang.*>.*html>).*/\1/p' \
| w3m -I 'utf-8' -T 'text/html' \
> "$pkgdir/usr/share/licenses/$pkgname/eula.txt"
}
|
